UMenu
Class UMenuMetalLookAndFeel

Core.Object
   |
   +--UWindow.UWindowBase
      |
      +--UWindow.UWindowLookAndFeel
         |
         +--UMenu.UMenuMetalLookAndFeel

/* Combo Drawing Functions */

/* Client Area Drawing Functions */

/* Framed Window Drawing Functions */

00001	class UMenuMetalLookAndFeel extends UWindowLookAndFeel;
00002	
00003	#exec TEXTURE IMPORT NAME=MetalActiveFrame FILE=Textures\M_ActiveFrame.bmp GROUP="Icons" FLAGS=2 MIPS=OFF
00004	#exec TEXTURE IMPORT NAME=MetalInactiveFrame FILE=Textures\M_InactiveFrame.bmp GROUP="Icons" FLAGS=2 MIPS=OFF
00005	#exec TEXTURE IMPORT NAME=MetalActiveFrameS FILE=Textures\M_ActiveFrameS.bmp GROUP="Icons" FLAGS=2 MIPS=OFF
00006	#exec TEXTURE IMPORT NAME=MetalInactiveFrameS FILE=Textures\M_InactiveFrameS.bmp GROUP="Icons" FLAGS=2 MIPS=OFF
00007	
00008	#exec TEXTURE IMPORT NAME=MetalMisc FILE=Textures\M_Misc.bmp GROUP="Icons" MIPS=OFF
00009	#exec TEXTURE IMPORT NAME=MetalButton FILE=Textures\M_SmallButton.pcx GROUP="Icons" MIPS=OFF
00010	
00011	#exec TEXTURE IMPORT NAME=MetalMenuArea FILE=Textures\M_MenuArea.bmp GROUP="Icons" MIPS=OFF
00012	#exec TEXTURE IMPORT NAME=MetalClientArea FILE=Textures\M_ClientArea.bmp GROUP="Icons" MIPS=OFF
00013	#exec TEXTURE IMPORT NAME=MetalMenuTL FILE=Textures\M_MenuTL.bmp GROUP="Icons" MIPS=OFF
00014	#exec TEXTURE IMPORT NAME=MetalMenuT FILE=Textures\M_MenuT.bmp GROUP="Icons" MIPS=OFF
00015	#exec TEXTURE IMPORT NAME=MetalMenuTR FILE=Textures\M_MenuTR.bmp GROUP="Icons" MIPS=OFF
00016	#exec TEXTURE IMPORT NAME=MetalMenuL FILE=Textures\M_MenuL.bmp GROUP="Icons" MIPS=OFF
00017	#exec TEXTURE IMPORT NAME=MetalMenuR FILE=Textures\M_MenuR.bmp GROUP="Icons" MIPS=OFF
00018	#exec TEXTURE IMPORT NAME=MetalMenuBL FILE=Textures\M_MenuBL.bmp GROUP="Icons" MIPS=OFF
00019	#exec TEXTURE IMPORT NAME=MetalMenuB FILE=Textures\M_MenuB.bmp GROUP="Icons" MIPS=OFF
00020	#exec TEXTURE IMPORT NAME=MetalMenuBR FILE=Textures\M_MenuBR.bmp GROUP="Icons" MIPS=OFF
00021	#exec TEXTURE IMPORT NAME=MetalMenuHL FILE=Textures\M_MenuHL.bmp GROUP="Icons" MIPS=OFF
00022	#exec TEXTURE IMPORT NAME=MetalMenuHM FILE=Textures\M_MenuHM.bmp GROUP="Icons" MIPS=OFF
00023	#exec TEXTURE IMPORT NAME=MetalMenuHR FILE=Textures\M_MenuHR.bmp GROUP="Icons" MIPS=OFF
00024	#exec TEXTURE IMPORT NAME=MetalMenuLine FILE=Textures\M_MenuLine.bmp GROUP="Icons" MIPS=OFF
00025	
00026	#exec TEXTURE IMPORT NAME=MetalBarL FILE=Textures\M_BarL.bmp GROUP="Icons" MIPS=OFF
00027	#exec TEXTURE IMPORT NAME=MetalBarTile FILE=Textures\M_BarTile.bmp GROUP="Icons" MIPS=OFF
00028	#exec TEXTURE IMPORT NAME=MetalBarMax FILE=Textures\M_BarMax.bmp GROUP="Icons" MIPS=OFF
00029	#exec TEXTURE IMPORT NAME=MetalBarWin FILE=Textures\M_BarWin.bmp GROUP="Icons" MIPS=OFF
00030	
00031	
00032	#exec TEXTURE IMPORT NAME=MetalBarInL FILE=Textures\M_BarInL.bmp GROUP="Icons" MIPS=OFF
00033	#exec TEXTURE IMPORT NAME=MetalBarInR FILE=Textures\M_BarInR.bmp GROUP="Icons" MIPS=OFF
00034	#exec TEXTURE IMPORT NAME=MetalBarInM FILE=Textures\M_BarInM.bmp GROUP="Icons" MIPS=OFF
00035	
00036	#exec TEXTURE IMPORT NAME=MetalBarOutL FILE=Textures\M_BarOutL.bmp GROUP="Icons" MIPS=OFF
00037	#exec TEXTURE IMPORT NAME=MetalBarOutR FILE=Textures\M_BarOutR.bmp GROUP="Icons" MIPS=OFF
00038	#exec TEXTURE IMPORT NAME=MetalBarOutM FILE=Textures\M_BarOutM.bmp GROUP="Icons" MIPS=OFF
00039	
00040	var() Region	SBUpUp;
00041	var() Region	SBUpDown;
00042	var() Region	SBUpDisabled;
00043	
00044	var() Region	SBDownUp;
00045	var() Region	SBDownDown;
00046	var() Region	SBDownDisabled;
00047	
00048	var() Region	SBLeftUp;
00049	var() Region	SBLeftDown;
00050	var() Region	SBLeftDisabled;
00051	
00052	var() Region	SBRightUp;
00053	var() Region	SBRightDown;
00054	var() Region	SBRightDisabled;
00055	
00056	var() Region	SBBackground;
00057	
00058	var() Region	FrameSBL;
00059	var() Region	FrameSB;
00060	var() Region	FrameSBR;
00061	
00062	var() Region	CloseBoxUp;
00063	var() Region	CloseBoxDown;
00064	var() int		CloseBoxOffsetX;
00065	var() int		CloseBoxOffsetY;
00066	
00067	
00068	const SIZEBORDER = 3;
00069	const BRSIZEBORDER = 15;
00070	
00071	/* Framed Window Drawing Functions */
00072	function FW_DrawWindowFrame(UWindowFramedWindow W, Canvas C)
00073	{
00074		local Texture T;
00075		local Region R, Temp;
00076	
00077		C.DrawColor.r = 255;
00078		C.DrawColor.g = 255;
00079		C.DrawColor.b = 255;
00080	
00081		T = W.GetLookAndFeelTexture();
00082	
00083		R = FrameTL;
00084		W.DrawStretchedTextureSegment( C, 0, 0, R.W, R.H, R.X, R.Y, R.W, R.H, T );
00085	
00086		R = FrameT;
00087		W.DrawStretchedTextureSegment( C, FrameTL.W, 0, 
00088										W.WinWidth - FrameTL.W
00089										- FrameTR.W,
00090										R.H, R.X, R.Y, R.W, R.H, T );
00091	
00092		R = FrameTR;
00093		W.DrawStretchedTextureSegment( C, W.WinWidth - R.W, 0, R.W, R.H, R.X, R.Y, R.W, R.H, T );
00094		
00095	
00096		if(W.bStatusBar)
00097			Temp = FrameSBL;
00098		else
00099			Temp = FrameBL;
00100		
00101		R = FrameL;
00102		W.DrawStretchedTextureSegment( C, 0, FrameTL.H,
00103										R.W,  
00104										W.WinHeight - FrameTL.H
00105										- Temp.H,
00106										R.X, R.Y, R.W, R.H, T );
00107	
00108		R = FrameR;
00109		W.DrawStretchedTextureSegment( C, W.WinWidth - R.W, FrameTL.H,
00110										R.W,  
00111										W.WinHeight - FrameTL.H
00112										- Temp.H,
00113										R.X, R.Y, R.W, R.H, T );
00114	
00115		if(W.bStatusBar)
00116			R = FrameSBL;
00117		else
00118			R = FrameBL;
00119		W.DrawStretchedTextureSegment( C, 0, W.WinHeight - R.H, R.W, R.H, R.X, R.Y, R.W, R.H, T );
00120	
00121		if(W.bStatusBar)
00122		{
00123			R = FrameSB;
00124			W.DrawStretchedTextureSegment( C, FrameBL.W, W.WinHeight - R.H, 
00125											W.WinWidth - FrameSBL.W
00126											- FrameSBR.W,
00127											R.H, R.X, R.Y, R.W, R.H, T );
00128		}
00129		else
00130		{
00131			R = FrameB;
00132			W.DrawStretchedTextureSegment( C, FrameBL.W, W.WinHeight - R.H, 
00133											W.WinWidth - FrameBL.W
00134											- FrameBR.W,
00135											R.H, R.X, R.Y, R.W, R.H, T );
00136		}
00137	
00138		if(W.bStatusBar)
00139			R = FrameSBR;
00140		else
00141			R = FrameBR;
00142		W.DrawStretchedTextureSegment( C, W.WinWidth - R.W, W.WinHeight - R.H, R.W, R.H, R.X, R.Y, 
00143										R.W, R.H, T );
00144	
00145	
00146		if(W.ParentWindow.ActiveWindow == W)
00147		{
00148			C.DrawColor = FrameActiveTitleColor;
00149			C.Font = W.Root.Fonts[W.F_Bold];
00150		}
00151		else
00152		{
00153			C.DrawColor = FrameInactiveTitleColor;
00154			C.Font = W.Root.Fonts[W.F_Normal];
00155		}
00156	
00157	
00158		W.ClipTextWidth(C, FrameTitleX, FrameTitleY, 
00159						W.WindowTitle, W.WinWidth - 22);
00160	
00161		if(W.bStatusBar) 
00162		{
00163			C.Font = W.Root.Fonts[W.F_Normal];
00164			C.DrawColor.r = 0;
00165			C.DrawColor.g = 0;
00166			C.DrawColor.b = 0;
00167	
00168			W.ClipTextWidth(C, 6, W.WinHeight - 13, W.StatusBarText, W.WinWidth - 22);
00169	
00170			C.DrawColor.r = 255;
00171			C.DrawColor.g = 255;
00172			C.DrawColor.b = 255;
00173		}
00174	}
00175	
00176	function FW_SetupFrameButtons(UWindowFramedWindow W, Canvas C)
00177	{
00178		local Texture T;
00179	
00180		T = W.GetLookAndFeelTexture();
00181	
00182		W.CloseBox.WinLeft = W.WinWidth - CloseBoxOffsetX - CloseBoxUp.W;
00183		W.CloseBox.WinTop = CloseBoxOffsetY;
00184	
00185		W.CloseBox.SetSize(CloseBoxUp.W, CloseBoxUp.H);
00186		W.CloseBox.bUseRegion = True;
00187	
00188		W.CloseBox.UpTexture = T;
00189		W.CloseBox.DownTexture = T;
00190		W.CloseBox.OverTexture = T;
00191		W.CloseBox.DisabledTexture = T;
00192	
00193		W.CloseBox.UpRegion = CloseBoxUp;
00194		W.CloseBox.DownRegion = CloseBoxDown;
00195		W.CloseBox.OverRegion = CloseBoxUp;
00196		W.CloseBox.DisabledRegion = CloseBoxUp;
00197	}
00198	
00199	function Region FW_GetClientArea(UWindowFramedWindow W)
00200	{
00201		local Region R;
00202	
00203		R.X = FrameL.W;
00204		R.Y	= FrameT.H;
00205		R.W = W.WinWidth - (FrameL.W + FrameR.W);
00206		if(W.bStatusBar) 
00207			R.H = W.WinHeight - (FrameT.H + FrameSB.H);
00208		else
00209			R.H = W.WinHeight - (FrameT.H + FrameB.H);
00210	
00211		return R;
00212	}
00213	
00214	
00215	function FrameHitTest FW_HitTest(UWindowFramedWindow W, float X, float Y)
00216	{
00217		if((X >= 3) && (X <= W.WinWidth-3) && (Y >= 3) && (Y <= 14))
00218			return HT_TitleBar;
00219		if((X < BRSIZEBORDER && Y < SIZEBORDER) || (X < SIZEBORDER && Y < BRSIZEBORDER)) 
00220			return HT_NW;
00221		if((X > W.WinWidth - SIZEBORDER && Y < BRSIZEBORDER) || (X > W.WinWidth - BRSIZEBORDER && Y < SIZEBORDER))
00222			return HT_NE;
00223		if((X < BRSIZEBORDER && Y > W.WinHeight - SIZEBORDER)|| (X < SIZEBORDER && Y > W.WinHeight - BRSIZEBORDER)) 
00224			return HT_SW;
00225		if((X > W.WinWidth - BRSIZEBORDER) && (Y > W.WinHeight - BRSIZEBORDER))
00226			return HT_SE;
00227		if(Y < SIZEBORDER)
00228			return HT_N;
00229		if(Y > W.WinHeight - SIZEBORDER)
00230			return HT_S;
00231		if(X < SIZEBORDER)
00232			return HT_W;
00233		if(X > W.WinWidth - SIZEBORDER)	
00234			return HT_E;
00235	
00236		return HT_None;	
00237	}
00238	
00239	/* Client Area Drawing Functions */
00240	function DrawClientArea(UWindowClientWindow W, Canvas C)
00241	{
00242		W.DrawClippedTexture(C, 0, 0, Texture'MetalMenuTL');
00243		W.DrawStretchedTexture(C, 2, 0, W.WinWidth-4, 2, Texture'MetalMenuT');
00244		W.DrawClippedTexture(C, W.WinWidth-2, 0, Texture'MetalMenuTR');
00245	
00246		W.DrawClippedTexture(C, 0, W.WinHeight-2, Texture'MetalMenuBL');
00247		W.DrawStretchedTexture(C, 2, W.WinHeight-2, W.WinWidth-4, 2, Texture'MetalMenuB');
00248		W.DrawClippedTexture(C, W.WinWidth-2, W.WinHeight-2, Texture'MetalMenuBR');
00249	
00250		W.DrawStretchedTexture(C, 0, 2, 2, W.WinHeight-4, Texture'MetalMenuL');
00251		W.DrawStretchedTexture(C, W.WinWidth-2, 2, 2, W.WinHeight-4, Texture'MetalMenuR');
00252	
00253		W.DrawStretchedTexture(C, 2, 2, W.WinWidth-4, W.WinHeight-4, Texture'MetalClientArea');
00254	}
00255	
00256	
00257	/* Combo Drawing Functions */
00258	
00259	function Combo_SetupSizes(UWindowComboControl W, Canvas C)
00260	{
00261		local float TW, TH;
00262	
00263		C.Font = W.Root.Fonts[W.Font];
00264		W.TextSize(C, W.Text, TW, TH);
00265		
00266		W.WinHeight = 12 + MiscBevelT[2].H + MiscBevelB[2].H;
00267		
00268		switch(W.Align)
00269		{
00270		case TA_Left:
00271			W.EditAreaDrawX = W.WinWidth - W.EditBoxWidth;
00272			W.TextX = 0;
00273			break;
00274		case TA_Right:
00275			W.EditAreaDrawX = 0;	
00276			W.TextX = W.WinWidth - TW;
00277			break;
00278		case TA_Center:
00279			W.EditAreaDrawX = (W.WinWidth - W.EditBoxWidth) / 2;
00280			W.TextX = (W.WinWidth - TW) / 2;
00281			break;
00282		}
00283	
00284		W.EditAreaDrawY = (W.WinHeight - 2) / 2;
00285		W.TextY = (W.WinHeight - TH) / 2;
00286	
00287		W.EditBox.WinLeft = W.EditAreaDrawX + MiscBevelL[2].W;
00288		W.EditBox.WinTop = MiscBevelT[2].H;
00289		W.Button.WinWidth = ComboBtnUp.W;
00290	
00291		if(W.bButtons)
00292		{
00293			W.EditBox.WinWidth = W.EditBoxWidth - MiscBevelL[2].W - MiscBevelR[2].W - ComboBtnUp.W - SBLeftUp.W - SBRightUp.W;
00294			W.EditBox.WinHeight = W.WinHeight - MiscBevelT[2].H - MiscBevelB[2].H;
00295			W.Button.WinLeft = W.WinWidth - ComboBtnUp.W - MiscBevelR[2].W - SBLeftUp.W - SBRightUp.W;
00296			W.Button.WinTop = W.EditBox.WinTop;
00297	
00298			W.LeftButton.WinLeft = W.WinWidth - MiscBevelR[2].W - SBLeftUp.W - SBRightUp.W;
00299			W.LeftButton.WinTop = W.EditBox.WinTop;
00300			W.RightButton.WinLeft = W.WinWidth - MiscBevelR[2].W - SBRightUp.W;
00301			W.RightButton.WinTop = W.EditBox.WinTop;
00302	
00303			W.LeftButton.WinWidth = SBLeftUp.W;
00304			W.LeftButton.WinHeight = SBLeftUp.H;
00305			W.RightButton.WinWidth = SBRightUp.W;
00306			W.RightButton.WinHeight = SBRightUp.H;
00307		}
00308		else
00309		{
00310			W.EditBox.WinWidth = W.EditBoxWidth - MiscBevelL[2].W - MiscBevelR[2].W - ComboBtnUp.W;
00311			W.EditBox.WinHeight = W.WinHeight - MiscBevelT[2].H - MiscBevelB[2].H;
00312			W.Button.WinLeft = W.WinWidth - ComboBtnUp.W - MiscBevelR[2].W;
00313			W.Button.WinTop = W.EditBox.WinTop;
00314		}
00315		W.Button.WinHeight = W.EditBox.WinHeight;
00316	}
00317	
00318	function Combo_Draw(UWindowComboControl W, Canvas C)
00319	{
00320		W.DrawMiscBevel(C, W.EditAreaDrawX, 0, W.EditBoxWidth, W.WinHeight, Misc, 2);
00321	
00322		if(W.Text != "")
00323		{
00324			C.DrawColor = W.TextColor;
00325			W.ClipText(C, W.TextX, W.TextY, W.Text);
00326			C.DrawColor.R = 255;
00327			C.DrawColor.G = 255;
00328			C.DrawColor.B = 255;
00329		}
00330	}
00331	
00332	function ComboList_DrawBackground(UWindowComboList W, Canvas C)
00333	{
00334		W.DrawClippedTexture(C, 0, 0, Texture'UMenu.MetalMenuTL');
00335		W.DrawStretchedTexture(C, 4, 0, W.WinWidth-8, 4, Texture'UMenu.MetalMenuT');
00336		W.DrawClippedTexture(C, W.WinWidth-4, 0, Texture'UMenu.MetalMenuTR');
00337	
00338		W.DrawClippedTexture(C, 0, W.WinHeight-4, Texture'UMenu.MetalMenuBL');
00339		W.DrawStretchedTexture(C, 4, W.WinHeight-4, W.WinWidth-8, 4, Texture'UMenu.MetalMenuB');
00340		W.DrawClippedTexture(C, W.WinWidth-4, W.WinHeight-4, Texture'UMenu.MetalMenuBR');
00341	
00342		W.DrawStretchedTexture(C, 0, 4, 4, W.WinHeight-8, Texture'UMenu.MetalMenuL');
00343		W.DrawStretchedTexture(C, W.WinWidth-4, 4, 4, W.WinHeight-8, Texture'UMenu.MetalMenuR');
00344	
00345		W.DrawStretchedTexture(C, 4, 4, W.WinWidth-8, W.WinHeight-8, Texture'UMenu.MetalMenuArea');
00346	}
00347	
00348	function ComboList_DrawItem(UWindowComboList Combo, Canvas C, float X, float Y, float W, float H, string Text, bool bSelected)
00349	{
00350		C.DrawColor.R = 255;
00351		C.DrawColor.G = 255;
00352		C.DrawColor.B = 255;
00353	
00354		if(bSelected)
00355		{
00356			Combo.DrawClippedTexture(C, X, Y, Texture'UMenu.MetalMenuHL');
00357			Combo.DrawStretchedTexture(C, X + 4, Y, W - 8, 16, Texture'UMenu.MetalMenuHM');
00358			Combo.DrawClippedTexture(C, X + W - 4, Y, Texture'UMenu.MetalMenuHR');
00359			C.DrawColor.R = 0;
00360			C.DrawColor.G = 0;
00361			C.DrawColor.B = 0;
00362		}
00363		else
00364		{
00365			C.DrawColor.R = 0;
00366			C.DrawColor.G = 0;
00367			C.DrawColor.B = 0;
00368		}
00369	
00370		Combo.ClipText(C, X + Combo.TextBorder + 2, Y + 3, Text);
00371	}
00372	
00373	function Checkbox_SetupSizes(UWindowCheckbox W, Canvas C)
00374	{
00375		local float TW, TH;
00376	
00377		W.TextSize(C, W.Text, TW, TH);
00378		W.WinHeight = Max(TH+1, 16);
00379		
00380		switch(W.Align)
00381		{
00382		case TA_Left:
00383			W.ImageX = W.WinWidth - 16;
00384			W.TextX = 0;
00385			break;
00386		case TA_Right:
00387			W.ImageX = 0;	
00388			W.TextX = W.WinWidth - TW;
00389			break;
00390		case TA_Center:
00391			W.ImageX = (W.WinWidth - 16) / 2;
00392			W.TextX = (W.WinWidth - TW) / 2;
00393			break;
00394		}
00395	
00396		W.ImageY = (W.WinHeight - 16) / 2;
00397		W.TextY = (W.WinHeight - TH) / 2;
00398	
00399		if(W.bChecked) 
00400		{
00401			W.UpTexture = Texture'ChkChecked';
00402			W.DownTexture = Texture'ChkChecked';
00403			W.OverTexture = Texture'ChkChecked';
00404			W.DisabledTexture = Texture'ChkCheckedDisabled';
00405		}
00406		else 
00407		{
00408			W.UpTexture = Texture'ChkUnchecked';
00409			W.DownTexture = Texture'ChkUnchecked';
00410			W.OverTexture = Texture'ChkUnchecked';
00411			W.DisabledTexture = Texture'ChkUncheckedDisabled';
00412		}
00413	}
00414	
00415	function Combo_GetButtonBitmaps(UWindowComboButton W)
00416	{
00417		local Texture T;
00418	
00419		T = W.GetLookAndFeelTexture();
00420		
00421		W.bUseRegion = True;
00422	
00423		W.UpTexture = T;
00424		W.DownTexture = T;
00425		W.OverTexture = T;
00426		W.DisabledTexture = T;
00427	
00428		W.UpRegion = ComboBtnUp;
00429		W.DownRegion = ComboBtnDown;
00430		W.OverRegion = ComboBtnUp;
00431		W.DisabledRegion = ComboBtnDisabled;
00432	}
00433	
00434	function Combo_SetupLeftButton(UWindowComboLeftButton W)
00435	{
00436		local Texture T;
00437	
00438		T = W.GetLookAndFeelTexture();
00439	
00440		W.bUseRegion = True;
00441	
00442		W.UpTexture = T;
00443		W.DownTexture = T;
00444		W.OverTexture = T;
00445		W.DisabledTexture = T;
00446	
00447		W.UpRegion = SBLeftUp;
00448		W.DownRegion = SBLeftDown;
00449		W.OverRegion = SBLeftUp;
00450		W.DisabledRegion = SBLeftDisabled;
00451	}
00452	
00453	function Combo_SetupRightButton(UWindowComboRightButton W)
00454	{
00455		local Texture T;
00456	
00457		T = W.GetLookAndFeelTexture();
00458	
00459		W.bUseRegion = True;
00460	
00461		W.UpTexture = T;
00462		W.DownTexture = T;
00463		W.OverTexture = T;
00464		W.DisabledTexture = T;
00465	
00466		W.UpRegion = SBRightUp;
00467		W.DownRegion = SBRightDown;
00468		W.OverRegion = SBRightUp;
00469		W.DisabledRegion = SBRightDisabled;
00470	}
00471	
00472	
00473	
00474	function Editbox_SetupSizes(UWindowEditControl W, Canvas C)
00475	{
00476		local float TW, TH;
00477		local int B;
00478	
00479		B = EditBoxBevel;
00480			
00481		C.Font = W.Root.Fonts[W.Font];
00482		W.TextSize(C, W.Text, TW, TH);
00483		
00484		W.WinHeight = 12 + MiscBevelT[B].H + MiscBevelB[B].H;
00485		
00486		switch(W.Align)
00487		{
00488		case TA_Left:
00489			W.EditAreaDrawX = W.WinWidth - W.EditBoxWidth;
00490			W.TextX = 0;
00491			break;
00492		case TA_Right:
00493			W.EditAreaDrawX = 0;	
00494			W.TextX = W.WinWidth - TW;
00495			break;
00496		case TA_Center:
00497			W.EditAreaDrawX = (W.WinWidth - W.EditBoxWidth) / 2;
00498			W.TextX = (W.WinWidth - TW) / 2;
00499			break;
00500		}
00501	
00502		W.EditAreaDrawY = (W.WinHeight - 2) / 2;
00503		W.TextY = (W.WinHeight - TH) / 2;
00504	
00505		W.EditBox.WinLeft = W.EditAreaDrawX + MiscBevelL[B].W;
00506		W.EditBox.WinTop = MiscBevelT[B].H;
00507		W.EditBox.WinWidth = W.EditBoxWidth - MiscBevelL[B].W - MiscBevelR[B].W;
00508		W.EditBox.WinHeight = W.WinHeight - MiscBevelT[B].H - MiscBevelB[B].H;
00509	}
00510	
00511	function Editbox_Draw(UWindowEditControl W, Canvas C)
00512	{
00513		W.DrawMiscBevel(C, W.EditAreaDrawX, 0, W.EditBoxWidth, W.WinHeight, Misc, EditBoxBevel);
00514	
00515		if(W.Text != "")
00516		{
00517			C.DrawColor = W.TextColor;
00518			W.ClipText(C, W.TextX, W.TextY, W.Text);
00519			C.DrawColor.R = 255;
00520			C.DrawColor.G = 255;
00521			C.DrawColor.B = 255;
00522		}
00523	}
00524	
00525	function ControlFrame_SetupSizes(UWindowControlFrame W, Canvas C)
00526	{
00527		local int B;
00528	
00529		B = EditBoxBevel;
00530			
00531		W.Framed.WinLeft = MiscBevelL[B].W;
00532		W.Framed.WinTop = MiscBevelT[B].H;
00533		W.Framed.SetSize(W.WinWidth - MiscBevelL[B].W - MiscBevelR[B].W, W.WinHeight - MiscBevelT[B].H - MiscBevelB[B].H);
00534	}
00535	
00536	function ControlFrame_Draw(UWindowControlFrame W, Canvas C)
00537	{
00538		C.DrawColor.R = 255;
00539		C.DrawColor.G = 255;
00540		C.DrawColor.B = 255;
00541		
00542		W.DrawStretchedTexture(C, 0, 0, W.WinWidth, W.WinHeight, Texture'WhiteTexture');
00543		W.DrawMiscBevel(C, 0, 0, W.WinWidth, W.WinHeight, Misc, EditBoxBevel);
00544	}
00545	
00546	function Tab_DrawTab(UWindowTabControlTabArea Tab, Canvas C, bool bActiveTab, bool bLeftmostTab, float X, float Y, float W, float H, string Text, bool bShowText)
00547	{
00548		local Region R;
00549		local Texture T;
00550		local float TW, TH;
00551	
00552		C.DrawColor.R = 255;
00553		C.DrawColor.G = 255;
00554		C.DrawColor.B = 255;
00555	
00556		T = Tab.GetLookAndFeelTexture();
00557		
00558		if(bActiveTab)
00559		{
00560			R = TabSelectedL;
00561			Tab.DrawStretchedTextureSegment( C, X, Y, R.W, R.H, R.X, R.Y, R.W, R.H, T );
00562	
00563			R = TabSelectedM;
00564			Tab.DrawStretchedTextureSegment( C, X+TabSelectedL.W, Y, 
00565											W - TabSelectedL.W
00566											- TabSelectedR.W,
00567											R.H, R.X, R.Y, R.W, R.H, T );
00568	
00569			R = TabSelectedR;
00570			Tab.DrawStretchedTextureSegment( C, X + W - R.W, Y, R.W, R.H, R.X, R.Y, R.W, R.H, T );
00571	
00572			C.Font = Tab.Root.Fonts[Tab.F_Bold];
00573			C.DrawColor.R = 0;
00574			C.DrawColor.G = 0;
00575			C.DrawColor.B = 0;
00576	
00577			if(bShowText)
00578			{
00579				Tab.TextSize(C, Text, TW, TH);
00580				Tab.ClipText(C, X + (W-TW)/2, Y + 3, Text, True);
00581			}
00582		}
00583		else
00584		{
00585			R = TabUnselectedL;
00586			Tab.DrawStretchedTextureSegment( C, X, Y, R.W, R.H, R.X, R.Y, R.W, R.H, T );
00587	
00588			R = TabUnselectedM;
00589			Tab.DrawStretchedTextureSegment( C, X+TabUnselectedL.W, Y, 
00590											W - TabUnselectedL.W
00591											- TabUnselectedR.W,
00592											R.H, R.X, R.Y, R.W, R.H, T );
00593	
00594			R = TabUnselectedR;
00595			Tab.DrawStretchedTextureSegment( C, X + W - R.W, Y, R.W, R.H, R.X, R.Y, R.W, R.H, T );
00596	
00597			C.Font = Tab.Root.Fonts[Tab.F_Normal];
00598			C.DrawColor.R = 0;
00599			C.DrawColor.G = 0;
00600			C.DrawColor.B = 0;
00601	
00602			if(bShowText)
00603			{
00604				Tab.TextSize(C, Text, TW, TH);
00605				Tab.ClipText(C, X + (W-TW)/2, Y + 4, Text, True);
00606			}
00607		}
00608	}
00609	
00610	function SB_SetupUpButton(UWindowSBUpButton W)
00611	{
00612		local Texture T;
00613	
00614		T = W.GetLookAndFeelTexture();
00615	
00616		W.bUseRegion = True;
00617	
00618		W.UpTexture = T;
00619		W.DownTexture = T;
00620		W.OverTexture = T;
00621		W.DisabledTexture = T;
00622	
00623		W.UpRegion = SBUpUp;
00624		W.DownRegion = SBUpDown;
00625		W.OverRegion = SBUpUp;
00626		W.DisabledRegion = SBUpDisabled;
00627	}
00628	
00629	function SB_SetupDownButton(UWindowSBDownButton W)
00630	{
00631		local Texture T;
00632	
00633		T = W.GetLookAndFeelTexture();
00634	
00635		W.bUseRegion = True;
00636	
00637		W.UpTexture = T;
00638		W.DownTexture = T;
00639		W.OverTexture = T;
00640		W.DisabledTexture = T;
00641	
00642		W.UpRegion = SBDownUp;
00643		W.DownRegion = SBDownDown;
00644		W.OverRegion = SBDownUp;
00645		W.DisabledRegion = SBDownDisabled;
00646	}
00647	
00648	
00649	
00650	function SB_SetupLeftButton(UWindowSBLeftButton W)
00651	{
00652		local Texture T;
00653	
00654		T = W.GetLookAndFeelTexture();
00655	
00656		W.bUseRegion = True;
00657	
00658		W.UpTexture = T;
00659		W.DownTexture = T;
00660		W.OverTexture = T;
00661		W.DisabledTexture = T;
00662	
00663		W.UpRegion = SBLeftUp;
00664		W.DownRegion = SBLeftDown;
00665		W.OverRegion = SBLeftUp;
00666		W.DisabledRegion = SBLeftDisabled;
00667	}
00668	
00669	function SB_SetupRightButton(UWindowSBRightButton W)
00670	{
00671		local Texture T;
00672	
00673		T = W.GetLookAndFeelTexture();
00674	
00675		W.bUseRegion = True;
00676	
00677		W.UpTexture = T;
00678		W.DownTexture = T;
00679		W.OverTexture = T;
00680		W.DisabledTexture = T;
00681	
00682		W.UpRegion = SBRightUp;
00683		W.DownRegion = SBRightDown;
00684		W.OverRegion = SBRightUp;
00685		W.DisabledRegion = SBRightDisabled;
00686	}
00687	
00688	function SB_VDraw(UWindowVScrollbar W, Canvas C)
00689	{
00690		local Region R;
00691		local Texture T;
00692	
00693		T = W.GetLookAndFeelTexture();
00694	
00695		R = SBBackground;
00696		W.DrawStretchedTextureSegment( C, 0, 0, W.WinWidth, W.WinHeight, R.X, R.Y, R.W, R.H, T);
00697		
00698		if(!W.bDisabled)
00699		{
00700			W.DrawUpBevel( C, 0, W.ThumbStart, Size_ScrollbarWidth,	W.ThumbHeight, T);
00701		}
00702	}
00703	
00704	function SB_HDraw(UWindowHScrollbar W, Canvas C)
00705	{
00706		local Region R;
00707		local Texture T;
00708	
00709		T = W.GetLookAndFeelTexture();
00710	
00711		R = SBBackground;
00712		W.DrawStretchedTextureSegment( C, 0, 0, W.WinWidth, W.WinHeight, R.X, R.Y, R.W, R.H, T);
00713		
00714		if(!W.bDisabled) 
00715		{
00716			W.DrawUpBevel( C, W.ThumbStart, 0, W.ThumbWidth, Size_ScrollbarWidth, T);
00717		}
00718	}
00719	
00720	function Tab_SetupLeftButton(UWindowTabControlLeftButton W)
00721	{
00722		local Texture T;
00723	
00724		T = W.GetLookAndFeelTexture();
00725	
00726	
00727		W.WinWidth = Size_ScrollbarButtonHeight;
00728		W.WinHeight = Size_ScrollbarWidth;
00729		W.WinTop = Size_TabAreaHeight - W.WinHeight;
00730		W.WinLeft = W.ParentWindow.WinWidth - 2*W.WinWidth;
00731	
00732		W.bUseRegion = True;
00733	
00734		W.UpTexture = T;
00735		W.DownTexture = T;
00736		W.OverTexture = T;
00737		W.DisabledTexture = T;
00738	
00739		W.UpRegion = SBLeftUp;
00740		W.DownRegion = SBLeftDown;
00741		W.OverRegion = SBLeftUp;
00742		W.DisabledRegion = SBLeftDisabled;
00743	}
00744	
00745	function Tab_SetupRightButton(UWindowTabControlRightButton W)
00746	{
00747		local Texture T;
00748	
00749		T = W.GetLookAndFeelTexture();
00750	
00751		W.WinWidth = Size_ScrollbarButtonHeight;
00752		W.WinHeight = Size_ScrollbarWidth;
00753		W.WinTop = Size_TabAreaHeight - W.WinHeight;
00754		W.WinLeft = W.ParentWindow.WinWidth - W.WinWidth;
00755	
00756		W.bUseRegion = True;
00757	
00758		W.UpTexture = T;
00759		W.DownTexture = T;
00760		W.OverTexture = T;
00761		W.DisabledTexture = T;
00762	
00763		W.UpRegion = SBRightUp;
00764		W.DownRegion = SBRightDown;
00765		W.OverRegion = SBRightUp;
00766		W.DisabledRegion = SBRightDisabled;
00767	}
00768	
00769	function Tab_SetTabPageSize(UWindowPageControl W, UWindowPageWindow P)
00770	{
00771		P.WinLeft = 2;
00772		P.WinTop = W.TabArea.WinHeight-(TabSelectedM.H-TabUnselectedM.H) + 3;
00773		P.SetSize(W.WinWidth - 4, W.WinHeight-(W.TabArea.WinHeight-(TabSelectedM.H-TabUnselectedM.H)) - 6);
00774	}
00775	
00776	function Tab_DrawTabPageArea(UWindowPageControl W, Canvas C, UWindowPageWindow P)
00777	{
00778		W.DrawUpBevel( C, 0, W.TabArea.WinHeight-(TabSelectedM.H-TabUnselectedM.H), W.WinWidth, W.WinHeight-(W.TabArea.WinHeight-(TabSelectedM.H-TabUnselectedM.H)), W.GetLookAndFeelTexture());
00779	}
00780	
00781	function Tab_GetTabSize(UWindowTabControlTabArea Tab, Canvas C, string Text, out float W, out float H)
00782	{
00783		local float TW, TH;
00784	
00785		C.Font = Tab.Root.Fonts[Tab.F_Bold];
00786	
00787		Tab.TextSize( C, Text, TW, TH );
00788		W = TW + Size_TabSpacing;
00789		H = Size_TabAreaHeight;
00790	}
00791	
00792	function Menu_DrawMenuBar(UWindowMenuBar W, Canvas C)
00793	{
00794		W.DrawClippedTexture(C, 0, 0, Texture'UMenu.MetalBarL');
00795		W.DrawStretchedTexture( C, 16, 0, W.WinWidth - 32, 16, Texture'UMenu.MetalBarTile');
00796		W.DrawClippedTexture(C, W.WinWidth - 16, 0, Texture'UMenu.MetalBarWin');
00797	}
00798	
00799	function Menu_DrawMenuBarItem(UWindowMenuBar B, UWindowMenuBarItem I, float X, float Y, float W, float H, Canvas C)
00800	{
00801		if(B.Selected == I)
00802		{
00803			B.DrawClippedTexture(C, X, 0, Texture'MetalBarInL');
00804			B.DrawClippedTexture(C, X+W-1, 0, Texture'MetalBarInR');
00805			B.DrawStretchedTexture(C, X+1, 0, W-2, 16, Texture'MetalBarInM');
00806		}
00807		else
00808		if (B.Over == I)
00809		{
00810			B.DrawClippedTexture(C, X, 0, Texture'MetalBarOutL');
00811			B.DrawClippedTexture(C, X+W-1, 0, Texture'MetalBarOutR');
00812			B.DrawStretchedTexture(C, X+1, 0, W-2, 16, Texture'MetalBarOutM');
00813		}
00814	
00815		C.Font = B.Root.Fonts[F_Normal];
00816		C.DrawColor.R = 0;
00817		C.DrawColor.G = 0;
00818		C.DrawColor.B = 0;
00819	
00820		B.ClipText(C, X + B.SPACING / 2, 3, I.Caption, True);
00821	}
00822	
00823	function Menu_DrawPulldownMenuBackground(UWindowPulldownMenu W, Canvas C)
00824	{
00825		W.DrawClippedTexture(C, 0, 0, Texture'UMenu.MetalMenuTL');
00826		W.DrawStretchedTexture(C, 4, 0, W.WinWidth-8, 4, Texture'UMenu.MetalMenuT');
00827		W.DrawClippedTexture(C, W.WinWidth-4, 0, Texture'UMenu.MetalMenuTR');
00828	
00829		W.DrawClippedTexture(C, 0, W.WinHeight-4, Texture'UMenu.MetalMenuBL');
00830		W.DrawStretchedTexture(C, 4, W.WinHeight-4, W.WinWidth-8, 4, Texture'UMenu.MetalMenuB');
00831		W.DrawClippedTexture(C, W.WinWidth-4, W.WinHeight-4, Texture'UMenu.MetalMenuBR');
00832	
00833		W.DrawStretchedTexture(C, 0, 4, 4, W.WinHeight-8, Texture'UMenu.MetalMenuL');
00834		W.DrawStretchedTexture(C, W.WinWidth-4, 4, 4, W.WinHeight-8, Texture'UMenu.MetalMenuR');
00835		W.DrawStretchedTexture(C, 4, 4, W.WinWidth-8, W.WinHeight-8, Texture'UMenu.MetalMenuArea');
00836	}
00837	
00838	function Menu_DrawPulldownMenuItem(UWindowPulldownMenu M, UWindowPulldownMenuItem Item, Canvas C, float X, float Y, float W, float H, bool bSelected)
00839	{
00840		C.DrawColor.R = 255;
00841		C.DrawColor.G = 255;
00842		C.DrawColor.B = 255;
00843	
00844		Item.ItemTop = Y + M.WinTop;
00845	
00846		if(Item.Caption == "-")
00847		{
00848			C.DrawColor.R = 255;
00849			C.DrawColor.G = 255;
00850			C.DrawColor.B = 255;
00851			M.DrawStretchedTexture(C, X, Y+5, W, 2, Texture'UMenu.MetalMenuLine');
00852			return;
00853		}
00854	
00855		C.Font = M.Root.Fonts[F_Normal];
00856	
00857		if(bSelected)
00858		{
00859			M.DrawClippedTexture(C, X, Y, Texture'UMenu.MetalMenuHL');
00860			M.DrawStretchedTexture(C, X + 4, Y, W - 8, 16, Texture'UMenu.MetalMenuHM');
00861			M.DrawClippedTexture(C, X + W - 4, Y, Texture'UMenu.MetalMenuHR');
00862		}
00863	
00864		if(Item.bDisabled) 
00865		{
00866			// Black Shadow
00867			C.DrawColor.R = 96;
00868			C.DrawColor.G = 96;
00869			C.DrawColor.B = 96;
00870		}
00871		else
00872		{
00873			C.DrawColor.R = 0;
00874			C.DrawColor.G = 0;
00875			C.DrawColor.B = 0;
00876		}
00877	
00878		// DrawColor will render the tick black white or gray.
00879		if(Item.bChecked)
00880			M.DrawClippedTexture(C, X + 1, Y + 3, Texture'MenuTick');
00881	
00882		if(Item.SubMenu != None)
00883			M.DrawClippedTexture(C, X + W - 9, Y + 3, Texture'MenuSubArrow');
00884	
00885		M.ClipText(C, X + M.TextBorder + 2, Y + 3, Item.Caption, True);	
00886	}
00887	
00888	function Button_DrawSmallButton(UWindowSmallButton B, Canvas C)
00889	{
00890		local float Y;
00891	
00892		if(B.bDisabled)
00893			Y = 34;
00894		else
00895		if(B.bMouseDown)
00896			Y = 17;
00897		else
00898			Y = 0;
00899	
00900		B.DrawStretchedTextureSegment(C, 0, 0, 3, 16, 0, Y, 3, 16, Texture'MetalButton');
00901		B.DrawStretchedTextureSegment(C, B.WinWidth - 3, 0, 3, 16, 45, Y, 3, 16, Texture'MetalButton');
00902		B.DrawStretchedTextureSegment(C, 3, 0, B.WinWidth-6, 16, 3, Y, 42, 16, Texture'MetalButton');
00903	}
00904	
00905	simulated function PlayMenuSound(UWindowWindow W, MenuSound S)
00906	{
00907		switch(S)
00908		{
00909		case MS_MenuPullDown:
00910			W.GetPlayerOwner().PlaySound(sound'WindowOpen');
00911			break;
00912		case MS_MenuCloseUp:
00913			break;
00914		case MS_MenuItem:
00915			W.GetPlayerOwner().PlaySound(sound'LittleSelect');
00916			break;
00917		case MS_WindowOpen:
00918			W.GetPlayerOwner().PlaySound(sound'BigSelect');
00919			break;
00920		case MS_WindowClose:
00921			break;
00922		case MS_ChangeTab:
00923			W.GetPlayerOwner().PlaySound(sound'LittleSelect');
00924			break;
00925			
00926		}
00927	}
00928	
00929	defaultproperties
00930	{
00931	     SBUpUp=(X=20,Y=16,W=12,H=10)
00932	     SBUpDown=(X=32,Y=16,W=12,H=10)
00933	     SBUpDisabled=(X=44,Y=16,W=12,H=10)
00934	     SBDownUp=(X=20,Y=26,W=12,H=10)
00935	     SBDownDown=(X=32,Y=26,W=12,H=10)
00936	     SBDownDisabled=(X=44,Y=26,W=12,H=10)
00937	     SBLeftUp=(X=20,Y=48,W=10,H=12)
00938	     SBLeftDown=(X=30,Y=48,W=10,H=12)
00939	     SBLeftDisabled=(X=40,Y=48,W=10,H=12)
00940	     SBRightUp=(X=20,Y=36,W=10,H=12)
00941	     SBRightDown=(X=30,Y=36,W=10,H=12)
00942	     SBRightDisabled=(X=40,Y=36,W=10,H=12)
00943	     SBBackground=(X=4,Y=79,W=1,H=1)
00944	     FrameSBL=(Y=112,W=2,H=16)
00945	     FrameSB=(X=32,Y=112,W=1,H=16)
00946	     FrameSBR=(X=112,Y=112,W=16,H=16)
00947	     CloseBoxUp=(X=4,Y=32,W=11,H=11)
00948	     CloseBoxDown=(X=4,Y=43,W=11,H=11)
00949	     CloseBoxOffsetX=2
00950	     CloseBoxOffsetY=2
00951	     Active=Texture'UMenu.Icons.MetalActiveFrame'
00952	     Inactive=Texture'UMenu.Icons.MetalInactiveFrame'
00953	     ActiveS=Texture'UMenu.Icons.MetalActiveFrameS'
00954	     InactiveS=Texture'UMenu.Icons.MetalInactiveFrameS'
00955	     Misc=Texture'UMenu.Icons.MetalMisc'
00956	     FrameTL=(W=2,H=16)
00957	     FrameT=(X=32,W=1,H=16)
00958	     FrameTR=(X=126,W=2,H=16)
00959	     FrameL=(Y=32,W=2,H=1)
00960	     FrameR=(X=126,Y=32,W=2,H=1)
00961	     FrameBL=(Y=125,W=2,H=3)
00962	     FrameB=(X=32,Y=125,W=1,H=3)
00963	     FrameBR=(X=126,Y=125,W=2,H=3)
00964	     FrameInactiveTitleColor=(R=255,G=255,B=255)
00965	     HeadingInActiveTitleColor=(R=255,G=255,B=255)
00966	     FrameTitleX=6
00967	     FrameTitleY=2
00968	     BevelUpTL=(X=4,Y=16,W=2,H=2)
00969	     BevelUpT=(X=10,Y=16,W=1,H=2)
00970	     BevelUpTR=(X=18,Y=16,W=2,H=2)
00971	     BevelUpL=(X=4,Y=20,W=2,H=1)
00972	     BevelUpR=(X=18,Y=20,W=2,H=1)
00973	     BevelUpBL=(X=4,Y=30,W=2,H=2)
00974	     BevelUpB=(X=10,Y=30,W=1,H=2)
00975	     BevelUpBR=(X=18,Y=30,W=2,H=2)
00976	     BevelUpArea=(X=8,Y=20,W=1,H=1)
00977	     MiscBevelTL(0)=(Y=17,W=3,H=3)
00978	     MiscBevelTL(1)=(W=3,H=3)
00979	     MiscBevelTL(2)=(Y=33,W=2,H=2)
00980	     MiscBevelT(0)=(X=3,Y=17,W=116,H=3)
00981	     MiscBevelT(1)=(X=3,W=116,H=3)
00982	     MiscBevelT(2)=(X=2,Y=33,W=1,H=2)
00983	     MiscBevelTR(0)=(X=119,Y=17,W=3,H=3)
00984	     MiscBevelTR(1)=(X=119,W=3,H=3)
00985	     MiscBevelTR(2)=(X=11,Y=33,W=2,H=2)
00986	     MiscBevelL(0)=(Y=20,W=3,H=10)
00987	     MiscBevelL(1)=(Y=3,W=3,H=10)
00988	     MiscBevelL(2)=(Y=36,W=2,H=1)
00989	     MiscBevelR(0)=(X=119,Y=20,W=3,H=10)
00990	     MiscBevelR(1)=(X=119,Y=3,W=3,H=10)
00991	     MiscBevelR(2)=(X=11,Y=36,W=2,H=1)
00992	     MiscBevelBL(0)=(Y=30,W=3,H=3)
00993	     MiscBevelBL(1)=(Y=14,W=3,H=3)
00994	     MiscBevelBL(2)=(Y=44,W=2,H=2)
00995	     MiscBevelB(0)=(X=3,Y=30,W=116,H=3)
00996	     MiscBevelB(1)=(X=3,Y=14,W=116,H=3)
00997	     MiscBevelB(2)=(X=2,Y=44,W=1,H=2)
00998	     MiscBevelBR(0)=(X=119,Y=30,W=3,H=3)
00999	     MiscBevelBR(1)=(X=119,Y=14,W=3,H=3)
01000	     MiscBevelBR(2)=(X=11,Y=44,W=2,H=2)
01001	     MiscBevelArea(0)=(X=3,Y=20,W=116,H=10)
01002	     MiscBevelArea(1)=(X=3,Y=3,W=116,H=10)
01003	     MiscBevelArea(2)=(X=2,Y=35,W=9,H=9)
01004	     ComboBtnUp=(X=20,Y=60,W=12,H=12)
01005	     ComboBtnDown=(X=32,Y=60,W=12,H=12)
01006	     ComboBtnDisabled=(X=44,Y=60,W=12,H=12)
01007	     ColumnHeadingHeight=13
01008	     HLine=(X=5,Y=78,W=1,H=2)
01009	     EditBoxBevel=2
01010	     TabSelectedL=(X=4,Y=80,W=3,H=17)
01011	     TabSelectedM=(X=7,Y=80,W=1,H=17)
01012	     TabSelectedR=(X=55,Y=80,W=2,H=17)
01013	     TabUnselectedL=(X=57,Y=80,W=3,H=15)
01014	     TabUnselectedM=(X=60,Y=80,W=1,H=15)
01015	     TabUnselectedR=(X=109,Y=80,W=2,H=15)
01016	     TabBackground=(X=4,Y=79,W=1,H=1)
01017	     Size_ScrollbarWidth=12.000000
01018	     Size_ScrollbarButtonHeight=10.000000
01019	     Size_MinScrollbarHeight=6.000000
01020	     Size_TabAreaHeight=15.000000
01021	     Size_TabAreaOverhangHeight=2.000000
01022	     Size_TabSpacing=20.000000
01023	     Size_TabXOffset=1.000000
01024	     Pulldown_ItemHeight=16.000000
01025	     Pulldown_VBorder=4.000000
01026	     Pulldown_HBorder=3.000000
01027	     Pulldown_TextBorder=9.000000
01028	}