Botpack
Class ChallengeCTFHUD

Core.Object
   |
   +--Engine.Actor
      |
      +--Engine.HUD
         |
         +--Botpack.ChallengeHUD
            |
            +--Botpack.ChallengeTeamHUD
               |
               +--Botpack.ChallengeCTFHUD

00001	//=============================================================================
00002	// ChallengeCTFHUD.
00003	//=============================================================================
00004	class ChallengeCTFHUD extends ChallengeTeamHUD;
00005	
00006	// Blue
00007	#exec TEXTURE IMPORT NAME=I_Capt FILE=TEXTURES\HUD\I_Capt.PCX GROUP="Icons" FLAGS=2 MIPS=OFF
00008	#exec TEXTURE IMPORT NAME=I_Down FILE=TEXTURES\HUD\I_Down.PCX GROUP="Icons" FLAGS=2 MIPS=OFF
00009	#exec TEXTURE IMPORT NAME=I_Home FILE=TEXTURES\HUD\I_Home.PCX GROUP="Icons" FLAGS=2 MIPS=OFF
00010	
00011	var CTFFlag MyFlag;
00012	
00013	function Timer()
00014	{
00015		Super.Timer();
00016	
00017		if ( (PlayerOwner == None) || (PawnOwner == None) )
00018			return;
00019		if ( PawnOwner.PlayerReplicationInfo.HasFlag != None )
00020			PlayerOwner.ReceiveLocalizedMessage( class'CTFMessage2', 0 );
00021		if ( (MyFlag != None) && !MyFlag.bHome )
00022			PlayerOwner.ReceiveLocalizedMessage( class'CTFMessage2', 1 );
00023	}
00024	
00025	simulated function PostRender( canvas Canvas )
00026	{
00027		local int X, Y, i;
00028		local CTFFlag Flag;
00029		local bool bAlt;
00030	
00031		Super.PostRender( Canvas );		
00032	
00033		if ( (PlayerOwner == None) || (PawnOwner == None) || (PlayerOwner.GameReplicationInfo == None)
00034			|| (PawnOwner.PlayerReplicationInfo == None)
00035			|| ((PlayerOwner.bShowMenu || PlayerOwner.bShowScores) && (Canvas.ClipX < 640)) )
00036			return;
00037	
00038		Canvas.Style = Style;
00039		if( !bHideHUD && !bHideTeamInfo )
00040		{
00041			X = Canvas.ClipX - 70 * Scale;
00042			Y = Canvas.ClipY - 350 * Scale;
00043				
00044			for ( i=0; i<4; i++ )
00045			{
00046				Flag = CTFReplicationInfo(PlayerOwner.GameReplicationInfo).FlagList[i];
00047				if ( Flag != None )
00048				{
00049					Canvas.DrawColor = TeamColor[Flag.Team];
00050					Canvas.SetPos(X,Y);
00051	
00052					if (Flag.Team == PawnOwner.PlayerReplicationInfo.Team)
00053						MyFlag = Flag;
00054					if ( Flag.bHome ) 
00055						Canvas.DrawIcon(texture'I_Home', Scale * 2);
00056					else if ( Flag.bHeld )
00057						Canvas.DrawIcon(texture'I_Capt', Scale * 2);
00058					else
00059						Canvas.DrawIcon(texture'I_Down', Scale * 2);
00060				}
00061				Y -= 150 * Scale;
00062			}
00063		}
00064	}
00065	
00066	simulated function DrawTeam(Canvas Canvas, TeamInfo TI)
00067	{
00068		local float XL, YL;
00069	
00070		if ( (TI != None) && (TI.Size > 0) )
00071		{
00072			Canvas.DrawColor = TeamColor[TI.TeamIndex];
00073			DrawBigNum(Canvas, int(TI.Score), Canvas.ClipX - 144 * Scale, Canvas.ClipY - 336 * Scale - (150 * Scale * TI.TeamIndex), 1);
00074		}
00075	}
00076	
00077	defaultproperties
00078	{
00079	     ServerInfoClass=Class'Botpack.ServerInfoCTF'
00080	}