UnrealShare
Class VRikersGame

Core.Object
   |
   +--Engine.Actor
      |
      +--Engine.Info
         |
         +--Engine.GameInfo
            |
            +--UnrealShare.UnrealGameInfo
               |
               +--UnrealShare.VRikersGame

00001	//=============================================================================
00002	// VRikersGame.
00003	//
00004	// no default weapon
00005	//
00006	//=============================================================================
00007	class VRikersGame extends UnrealGameInfo;
00008	
00009	event playerpawn Login
00010	(
00011		string Portal,
00012		string Options,
00013		out string Error,
00014		class<playerpawn> SpawnClass
00015	)
00016	{
00017		local PlayerPawn NewPlayer;
00018		NewPlayer = Super.Login(Portal, Options, Error, SpawnClass);
00019		if ( (NewPlayer != None)
00020			&& (NewPlayer.Health == NewPlayer.Default.Health)  )
00021		{
00022			NewPlayer.PlayerRestartState = 'PlayerWaking';
00023			NewPlayer.ViewRotation.Pitch = 16384;
00024			NewPlayer.Health = 12;
00025		}
00026		return NewPlayer;
00027	}
00028	
00029	function bool RestartPlayer(pawn aPlayer)	
00030	{
00031		local bool result;
00032	
00033		result = Super.RestartPlayer(aPlayer);
00034		if ( result )
00035		{
00036			aPlayer.Health = 12;
00037			aPlayer.ViewRotation.Pitch = 16384;
00038		}
00039		return result;
00040	}
00041	
00042	function int ReduceDamage(int Damage, name DamageType, pawn injured, pawn instigatedBy)
00043	{
00044		// no friendly fire always in coop
00045		if ( (instigatedBy != None) 
00046			&& instigatedBy.bIsPlayer && injured.bIsPlayer && (instigatedBy != injured) )
00047			return 0;
00048	
00049		return Super.ReduceDamage(Damage, DamageType, injured, instigatedBy);
00050	}
00051	
00052	function AddDefaultInventory(pawn PlayerPawn)
00053	{
00054		return;
00055	}
00056	
00057	function bool PickupQuery(Pawn Other, Inventory item)
00058	{
00059		if ( item.IsA('DispersionPistol') )
00060			DefaultWeapon = class'DispersionPistol';
00061		return Super.PickupQuery(Other, item);
00062	}
00063	
00064	defaultproperties
00065	{
00066	     bHumansOnly=True
00067	     DefaultWeapon=None
00068	}